На вход программе подается набор символов, заканчивающийся точкой (в программе на языке Бейсик символы можно вводить по одному в строке, пока не будет введена точка, или считывать данные из файла).... | Яндекс.Репетитор

Задание#T24413

На вход программе подается набор символов, заканчивающийся точкой (в программе на языке Бейсик символы можно вводить по одному в строке, пока не будет введена точка, или считывать данные из файла). Напишите эффективную, в том числе и по используемой памяти, программу (укажите используемую версию языка программирования, например, Borland Pascal 7.0), которая сначала будет определять, есть ли в этом наборе символы, соответствующие десятичным цифрам. Если такие символы есть, то можно ли переставить их так, чтобы полученное число было симметричным (читалось одинаково как слева направо, так и справа налево). Ведущих нулей в числе быть не должно, исключение – число 0, запись которого содержит ровно один ноль.

Если требуемое число составить невозможно, то программа должна вывести на экран слово «NO». А если возможно, то в первой строке следует вывести слово «YES», а во второй – искомое симметричное число. Если таких чисел несколько, то программа должна выводить максимальное из них. Например, пусть на вход подаются следующие символы:

Do not 911 to 09 do.

В данном случае программа должна вывести

YES
91019

Показать разбор

Содержание верного ответа

(допускаются иные формулировки ответа, не искажающие его смысл)

Программа читает все входные символы до точки один раз, подсчитывая в массиве, хранящем 10 целых чисел, количество каждой из цифр. Сами входные символы при этом не запоминаются. Затем проверяется — сколько в этом массиве нечетных элементов. Если больше одного, то задача решения не имеет. При наличии решения сначала печатается половина имеющихся цифр 9 (если таковые имеются, в случае нечетного числа цифр – меньшая половина), затем 8 и т.д. до 0, потом печатается цифра, которая встречается во входных данных нечетное число раз, а затем – оставшаяся половина цифр 0 (если таковые имеются, в случае нечетного числа цифр – меньшая половина), 1, и т.д. до 9. Если никаких цифр, кроме 0, во входных данных нет, то задача имеет решение, только если этот ноль единственный. Если нулей четное число, а ненулевая цифра единственная, то решения не существует.

Баллы начисляются только за программу, которая решает задачу хотя бы для одного частного случая (например, для строк, состоящих не более чем из 255 символов), или которая умеет только определять, имеет ли задача решение.

Пример правильной и эффективной программы

var a:array['0'..'9'] of integer;
  c, c_odd: char;
  i, k: integer;
  f: boolean;
begin
 for c:='0' to '9' do a[c]:=0;
 read(с);
 while c<>'.' do
  begin
   if c in ['0' .. '9'] then a[c] := a[c] + 1;
   read(c);
  end;
 k := 0; {количество цифр, встречающихся нечетное число раз}
 for c := '0' to '9' do
  if a[c] mod 2 = 1 then
   begin
    k := k + 1;
    c_odd := c
   end;
 f := (a['0'] = 1);
 for c := '1' to '9' do
  if (a[c] > 1) or (a[c] = 1) and (a['0'] = 0) then f := true;
 if (k > 1)or not f then writeln('NO') else
 begin
  writeln('YES');
  for c := '9' downto '0' do
   for i := 1 to a[c] div 2 do
    write(c);
  if k = 1 then
   write(c_odd);
  for c := '0' to '9' do
   for i := 1 to a[c] div 2 do
    write(c);
 end
end.

Критерии оценки

4 баллаПрограмма работает верно, т.е. определяет, имеет ли задача решение для любых входных данных произвольного размера, и строит максимальное искомое число, не сохраняя входные данные в строке или массиве символов. Программа просматривает входные данные один раз, в тексте программы не анализируется каждая цифра в отдельности. Допускается наличие в тексте программы одной синтаксической ошибки: пропущен или неверно указан знак пунктуации, неверно написано или пропущено зарезервированное слово языка программирования, не описана или неверно описана переменная, применяется операция, недопустимая для соответствующего типа данных (если одна и та же ошибка встречается несколько раз, то это считается одной ошибкой).

3 баллаПрограмма работает верно, но входные данные запоминаются в массиве символов или строке, или входные данные считываются несколько раз. Возможно, каждая цифра обрабатывается явным образом (10 операторов IF, в том числе с использованием многоточия, или оператор CASE, содержащий 10 вариантов). Возможно, сохраненные входные данные сортируются одним из стандартных алгоритмов сортировки путем перестановки входных символов, или ответ формируется путем перестановки входных цифр. Допускается наличие от одной до трех синтаксических ошибок, описанных выше. Три балла также выставляется, если в эффективной программе, удовлетворяющей критериям выставления 4 баллов, есть одна ошибка, не относящаяся к алгоритму решения задачи в целом, например, ошибка в принципиально верно организованном вводе данных или в обработке числа, состоящего из одних нулей или из четного числа нулей и одной ненулевой цифры.

2 баллаПрограмма работает в целом верно, эффективно или нет, но, возможно, выводит значение не максимального искомого числа. Возможно, в реализации алгоритма содержатся 1–2 ошибки (используется знак «/» вместо «\», «div» вместо «mod», выход за границу массива, перевод символов в числа, используется знак «<» вместо «<=», «or» вместо «and» и т.п.). Возможно, некорректно организовано считывание входных данных. Допускается наличие от одной до пяти синтаксических ошибок, описанных выше.

1 баллПрограмма, возможно, неверно работает при некоторых входных данных, например, при наличии цифры, которая встречается нечетное число раз. Возможно, выводит только «NO» или «YES» и не выводит искомое число, или выводит его неверно. При использовании сортировки допущены ошибки в ее реализации. Допускается до 4 различных ошибок в реализации алгоритма, в том числе описанных в критериях присвоения двух баллов. Допускается наличие от одной до семи синтаксических ошибок, описанных выше.

0 балловЗадание не выполнено или выполнено неверно.

Это задание в разделах:

ЕГЭ-2011 - Архив

Задание#T24413

Это задание в разделах:

Рекомендованные задания